Public Class Form1

    ''DataGridViewTextBoxEditingControlのイベントを処理する為の変数
    Private _EditingControl As DataGridViewTextBoxEditingControl

    ''セル編集が終了
    Private Sub DataGridView1_CellEndEdit(ByVal sender As Object _
                       , ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) _
                                                    Handles DataGridView1.CellEndEdit
        If Me._EditingControl IsNot Nothing Then
            RemoveHandler _EditingControl.KeyPress, AddressOf _EditingControl_KeyPress
            Me._EditingControl = Nothing
        End If
    End Sub

    ''セルを編集するコントロールが表示
    Private Sub DataGridView1_EditingControlShowing(ByVal sender As Object _
                       , ByVal e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) _
                                                           Handles DataGridView1.EditingControlShowing
        Me._EditingControl = TryCast(e.Control, DataGridViewTextBoxEditingControl)
        If Me._EditingControl IsNot Nothing Then
            AddHandler _EditingControl.KeyPress, AddressOf _EditingControl_KeyPress
        End If
    End Sub

    ''セル編集コントロールのKeyPressイベント
    Private Sub _EditingControl_KeyPress(ByVal sender As Object _
                                       , ByVal e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = Not Char.IsDigit(e.KeyChar)
    End Sub

End Class