ストロークの保存・読込

操作機能の実装で最低限の機能を実装しましたが、これに描画した内容を保存・読み込む機能を実装してみましょう。
保存・読込機能の実装は難しいと思われるかもしれませんが、InkCanvas?ではStrokes(StrokeCollection?)を利用する事により、数行のコードで実装する事ができます。

サンプルの画面レイアウト bookmark

上のような画面を作成します。XAMLコードは以下のようになっています。

保存処理 bookmark

保存ボタン(btnStrokeLoad?)が押された場合の処理は、以下のようになっています。

実際に保存処理を行っているのは、16-18行で、引数にStreamを指定して、Saveメソッドを呼び出しているだけです。
このSaveメソッドで保存されたファイルは、ISF (Ink Serialized Format)で保存されます。
また、Saveメソッドの第２引数にTrueを指定する事により、圧縮して保存する事も可能です。

読込処理 bookmark

読込ボタン(btnStrokeLoad?)が押された場合の処理は、以下のようになっています。

実際に読込処理を行っているのは、14-16行で、引数にStreamを指定して、StrokeCollection?を作成して、それをInkCanvas1のStrokesにセットしています。

全体のVBコード bookmark

Imports System.IO

Partial Public Class Window1
    Inherits Window

''ストロークデータファイルパス
    Private _InkDataPath As String = My.Application.Info.DirectoryPath & "\sample.ink"

Public Sub New()
        InitializeComponent()
        ''初期設定
        Me.rbtInk.IsChecked = True
    End Sub

Private Sub rbtInk_Checked(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) Handles rbtInk.Checked
        ''インクモードに設定
        Me.InkCanvas1.EditingMode = InkCanvasEditingMode.Ink
    End Sub

Private Sub rbtSelect_Checked(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) Handles rbtSelect.Checked
        ''選択モードに設定
        Me.InkCanvas1.EditingMode = InkCanvasEditingMode.Select
    End Sub

Private Sub rbtErase_Checked(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) Handles rbtErase.Checked
        ''ストローク消去モードに設定
        Me.InkCanvas1.EditingMode = InkCanvasEditingMode.EraseByStroke
    End Sub

Private Sub btnClear_Click(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) Handles btnClear.Click
        ''ストローク全消去
        Me.InkCanvas1.Strokes.Clear()
    End Sub

Private Sub btnStrokeLoad_Click(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) _
                    Handles btnStrokeLoad.Click
        ''ストロークデータの読込

''読込ファイルの有無チェック
        If Not My.Computer.FileSystem.FileExists(Me._InkDataPath) Then
            MessageBox.Show("ファイルが存在しません。", _
                            "警告", MessageBoxButton.OK)
            Exit Sub
        End If

''読込
        Using fs As New FileStream(Me._InkDataPath, FileMode.Open)
            Me.InkCanvas1.Strokes = New Ink.StrokeCollection(fs)
        End Using

End Sub

Private Sub btnStrokeSave_Click(ByVal sender As Object, _
                    ByVal e As System.Windows.RoutedEventArgs) _
                    Handles btnStrokeSave.Click
        ''ストロークデータの保存

''保存ファイルの有無チェック
        If My.Computer.FileSystem.FileExists(Me._InkDataPath) Then
            If MessageBox.Show("既にファイルは存在します。上書きしますか？", _
                    "確認", MessageBoxButton.YesNo) <> MessageBoxResult.Yes Then
                Exit Sub
            End If
            My.Computer.FileSystem.DeleteFile(Me._InkDataPath)
        End If

''保存
        Using fs As New FileStream(Me._InkDataPath, FileMode.CreateNew)
            Me.InkCanvas1.Strokes.Save(fs)
        End Using

End Sub
End Class

ストロークの保存・読込